Cara menghitung PPh pasal 21 atas suatu Penghasilan Kena Pajak dengan Rumus Excel – Apakah anda sedang mencari rumus excel untuk menghitung PPh 21 atas suatu Penghasilan Kena Pajak? ataukah sedang mencari rumus alternatif lain dengan algoritma yang berbeda? Excelku kali ini akan berbagi beragam varian Rumus Excel yang dapat memudahkan anda dalam menghitung Pajak Penghasilan dari Wajib Pajak Orang Pribadi. Mengambil dari tumpukan rumus excel yang pernah admin buat di waktu lampau dan dengan sedikit modifikasi agar lebih mudah dibaca inilah 8 varian Rumus Excel tersebut. 

Tapi tunggu dulu… sepertinya kurang afdol bila langsung ke daftar rumus pph 21, baca pendahuluan terlebih dahulu ya… untuk memastikan sama-sama berangkat dari titik yang sama oke.

Pendahuluan

Perlu digaris bawahi bahwa acuan tarif yang digunakan oleh Rumus Excel yang akan dibahas berikut ini adalah penggunaan Tarif Pajak Progresif sesuai Pasal 17 ayat (1) huruf a, yaitu sebagai berikut:

Lapisan PKP Tarif Pajak
 0 – 50juta  5%
 >50juta – 250juta  15%
 >250juta – 500juta  25%
 >500juta  30%
Dari ketentuan tersebut di atas dapat disimpulkan bahwa Tarif pasal 17 ayat (1) huruf a UU PPh bersifat progresif yang artinya tarif Pajak semakin besar pada setiap bertambahnya lapisan penghasilan kena pajak.

Perlu diingat bahwa untuk keperluan penerapan tarif pajak tersebut di atas maka jumlah Penghasilan Kena Pajak dibulatkan ke bawah dalam ribuan rupiah penuh. Perlu dicatat bahwa daftar rumus nantinya mengasumsikan bahwa sel yang menjadi rujukan sudah dibulatkan ke bawah dalam ribuan rupiah penuh. Harapannya agar pembaca tidak membuat “malas” duluan karena melihat panjangnya rumus, dengan menampilkan tampilan ringkasnya diharapkan menjadi lebih mudah dibaca dan dimengerti jalan ceritanya. Setelah memahami jalan cerita dari suatu rumus diharapkan selanjutnya fokus pada peningkatan robustness dari rumus tersebut. Doakan saja semoga harapan ini tercapai 😀

Rumus Excel PPh pasal 21

Berdasarkan PPh pasal 21 ayat (1) UU PPh, pemotongan pajak atas penghasilan sehubungan dengan pekerjaan, jasa, atau kegiatan dengan nama dan dalam bentuk apa pun yang diterima atau diperoleh Wajib Pajak orang pribadi dalam negeri menggunakan tarif pajak Pasal 17 ayat (1) huruf a UU PPh. Dengan tetap berpedoman pada pasal tersebut, kali ini Excelku fokus berbagi varian rumus tanpa rujukan suatu range tabel, namun hanya merujuk pada suatu range PKP (yang sudah dibulatkan ke bawah dalam ribuan rupiah penuh) dengan pengoperasian tarif serta penghasilan langsung pada rumus itu sendiri.

Dengan A5 merupakan nilai dari suatu Penghasilan Kena Pajak [!Positif & !pembulatan ke bawah dalam ribuan rupiah penuh],  maka berikut ini adalah 8 Varian Rumus Excel Perhitungan PPh pasal 21 atas suatu Penghasilan Kena Pajak (PKP):

1. Tanpa Fungsi Excel

=((A5<=50000000)*(A5*5%))+(((A5>50000000)*(A5<=250000000))*(2500000+((A5-50000000)*15%)))+(((A5>250000000)*(A5<=500000000))*(32500000+((A5-250000000)*25%)))+((A5>500000000)*(95000000+((A5-500000000)*30%)))

2. Memanfaatkan Fungsi IF

=IF(A5<=50000000,A5*5%,IF(A5<=250000000,2500000+((A5-50000000)*15%),IF(A5<=500000000,32500000+((A5-250000000)*25%),95000000+((A5-500000000)*30%))))

3. Memanfaatkan Fungsi MIN & SUMPRODUCT

=(MIN(50000000,A5)*5%)+SUMPRODUCT(--(A5>{50000000;250000000;500000000}), A5-{50000000;250000000;500000000},{15;10;5}%)

4. Memanfaatkan Fungsi INDEX & MATCH

=INDEX(({5;15;25;30}%*A5)-{0;5000000;30000000;55000000}, MATCH(1,1/(A5>={0;50000000;250000000;500000000})))

5. Memanfaatkan Fungsi MIN & MAX

=(MIN(MAX(0,A5),50000000)*5%)+(MIN(MAX(0,A5-50000000),200000000)*15%)+(MIN(MAX(0,A5-250000000),250000000)*25%)+(MAX(0,A5-500000000)*30%)

6. Memanfaatkan Fungsi MIN

=((A5*30%)-(MIN(A5,500000000)*5%)-(MIN(A5,250000000)*10%)-(MIN(A5,50000000)*10%))

7. Memanfaatkan Fungsi MAX

=(MAX(0,A5)*5%)+(MAX(0,A5-50000000)*10%)+(MAX(0,A5-250000000)*10%)

8. Memanfaatkan Fungsi MAX

=MAX(({5;15;25;30}%*A5)-{0;5000000;30000000;55000000})

PERHATIAN: Kedelapan rumus tersebut di atas mengasumsikan bahwa nilai PKP (dalam contoh tersebut di atas adalah sel A5) adalah sebuah angka, nilainya >=0 dan sudah dibulatkan ke bawah dalam ribuan rupiah penuh (bisa gunakan rumus =ROUND(A5,-3) untuk pembulatan tersebut). Sesuaikan rumus bila kondisinya berbeda. Rumus tersebut menggunakan pemisah argumen berupa tanda “,” (koma), apabila melakukan copy paste rumus langsung ke komputer pastikan anda telah mengubahnya sesuai dengan settingan pada Excel anda.

Mau menggunakan yang mana dari kedelapan rumus excel tersebut? Tidak hanya pilih yang pas di hati maupun pikiran anda namun juga calon pembaca rumus (selain anda)… karena yang lebih ringkas belum tentu dapat segera dipahami oleh pembaca (siapapun itu nantinya).

Simulasi Rumus Excel PPh pasal 21 atas Penghasilan Kena Pajak

Klik disini untuk mendownload file simulasi pembanding atas hasil dari kedelapan Rumus Excel tersebut.

Penutup

Demikianlah contoh perhitungan PPh 21 dengan 8 Rumus Excel PPh pasal 21 (Tarif Pajak Progresif Pasal 17 ayat (1) huruf a) yang dapat admin Excelku.com bagikan. Semoga dapat menambah teknik dan wawasan anda tentang Rumus Excel. Tentu tidak hanya 8 varian Rumus Excel saja yang dapat dilakukan untuk menghitung PPh 21 atas suatu Penghasilan Kena Pajak orang pribadi berdasarkan pasal 17 tersebut. Bila anda mempunyai varian rumus excel lainnya sudilah kiranya berbagi dengan kita-kita di sini, terimakasih 🙂

Related Posts:

SUBSCRIBE NOW!
Tidak mau ketinggalan tips dan trik unik dari Excelku?
  Privasi Email terjaga.
Daftarkan email Anda sekarang juga
You have successfully subscribed to our newsletter
Tidak mau ketinggalan tips dan trik unik dari Excelku?
Privasi Email terjaga.
Daftarkan email Anda sekarang juga
You have successfully subscribed to our newsletter
Subscribe Now
This is Photoshop's version of Lorem Ipsum. Proin gravida nibh vel velit auctor aliquet. Aenean sollicitudin, lorem quis bibendum auctor, nisi elit consequat ipsum, nec sagittis sem nibh id elit. Duis sed odio sit amet nibh vulputate cursus.
        
Subscribe & download
e-mail
Privasi Email terjaga.
Please enter your valid email address. The download link will be in your inbox within a moment.
Terimakasih...
Subscribe & download
e-mail
Privasi Email terjaga.
Please enter your valid email address. The download link will be in your inbox within a moment.
Terimakasih...
Subscribe sekarang juga
untuk mengunduh...
e-mail
Privasi email terjaga.
SUBSCRIBE
Tidak mau ketinggalan tips dan trik unik dari Excelku? Daftarkan email Anda sekarang juga. Privasi Email terjaga.
You have successfully subscribed to our newsletter
Subscribe & download
e-mail
Privasi Email terjaga.
Please enter your valid email address. The download link will be in your inbox within a moment.
Subscribe & download
e-mail
Privasi Email terjaga.
Please enter your valid email address. The download link will be in your inbox within a moment.